darktable/libgphoto2
1
0
Fork 0
Code Issues Packages Projects Releases Wiki Activity

Remove --with-doc-dir and --with-html-dir

Browse Source 
autoconf 2.59c has introduced docdir, htmldir, so we do not need to
have --with-doc-dir= and --with-html-dir= any more. --docdir= and
--htmldir= will do the job.
This commit is contained in:
Hans Ulrich Niedermann
2021-11-13 23:47:58 +01:00
parent 88b6c0dc26
commit 24cae685e1
6 changed files with 24 additions and 97 deletions
Download Patch File Download Diff File Expand all files Collapse all files

3
NEWS
View File

@@ -5,7 +5,8 @@ general:
* remove built-in rpm packaging (use distro packaging instead)
* remove linux-hotplug rule creation (removed from distros around 2006)
* remaining text which was iso-8859 is UTF-8 now (except one po file)
* To override docdir and htmldir, use configure arguments --docdir=
and --htmldir= instead of --with-doc-dir= and --with-html-dir=
ptp2:
* Nikon J1: capture fixed

3
configure.ac
View File

@@ -28,7 +28,7 @@ AM_INIT_AUTOMAKE([
dnl Notable tool releases and why they are important for us:
dnl
dnl autoconf 2012-04-25 2.69 (what libexif requires)
dnl autoconf 2006-04-12 2.59c (introduces localedir)
dnl autoconf 2006-04-12 2.59c (introduces localedir, docdir, htmldir)
dnl
dnl automake 2013-12-24 1.14.1 (what libexif requires)
dnl automake 2013-06-20 1.14 (introduces %reldir%, implies AM_PROG_CC_C_O)
@@ -579,7 +579,6 @@ GP_CAMLIBS_DEFINE()dnl
dnl --------------------------------------------------------------------
dnl documentation
dnl --------------------------------------------------------------------
GP_CHECK_DOC_DIR()dnl
GP_CHECK_DOXYGEN()dnl
GP_INTERNAL_DOCS()dnl
GP_BUILD_GTK_DOCS()dnl

1
libgphoto2_port/configure.ac
View File

@@ -524,7 +524,6 @@ AC_ARG_ENABLE([debug],
# gtk-doc?
# ----------------------------------------------------------------------
GP_CONFIG_MSG([Documentation])
GP_CHECK_DOC_DIR()dnl
GP_BUILD_GTK_DOCS()dnl

29
libgphoto2_port/gphoto-m4/gp-check-doxygen.m4
View File

@@ -1,20 +1,27 @@
dnl ####################################################################
dnl doxygen related stuff
dnl look for tools
dnl define substitutions for Doxyfile.in
AC_DEFUN([GP_CHECK_DOXYGEN],[dnl
AC_REQUIRE([GP_CHECK_DOC_DIR])dnl
AC_PATH_PROG([DOT], [dot], [false])
AC_PATH_PROG([DOXYGEN], [doxygen], [false])
AM_CONDITIONAL([HAVE_DOXYGEN], [test "x$DOXYGEN" != "xfalse"])
AM_CONDITIONAL([HAVE_DOT], [test "x$DOT" != "xfalse"])
if test "x$DOT" != "xfalse"; then
AC_SUBST([HAVE_DOT],[YES])
else
AC_SUBST([HAVE_DOT],[NO])
fi
dnl ####################################################################
dnl
AC_DEFUN([GP_CHECK_DOXYGEN], [dnl
dnl
AC_ARG_VAR([DOT], [graphviz dot directed graph drawing command])
AC_PATH_PROG([DOT], [dot], [no])
AM_CONDITIONAL([HAVE_DOT], [test "x$DOT" != xno])
dnl
AC_ARG_VAR([DOXYGEN], [software documentation generator command])
AC_PATH_PROG([DOXYGEN], [doxygen], [no])
AM_CONDITIONAL([HAVE_DOXYGEN], [test "x$DOXYGEN" != xno])
dnl
dnl Substitutions for Doxyfile.in
AM_COND_IF([HAVE_DOT],
[AC_SUBST([HAVE_DOT], [YES])],
[AC_SUBST([HAVE_DOT], [NO])])
AC_SUBST([HTML_APIDOC_DIR], ["${PACKAGE_TARNAME}-api.html"])
AC_SUBST([DOXYGEN_OUTPUT_DIR], [doxygen-output])
AC_SUBST([HTML_APIDOC_INTERNALS_DIR], ["${PACKAGE_TARNAME}-internals.html"])
dnl
])dnl
dnl
dnl

81
libgphoto2_port/gphoto-m4/gp-documentation.m4
View File

@@ -1,67 +1,11 @@
dnl
dnl check where to install documentation
dnl
dnl determines documentation "root directory", i.e. the directory
dnl where all documentation will be placed in
dnl
dnl
AC_DEFUN([GP_CHECK_DOC_DIR],
[
AC_BEFORE([$0], [GP_BUILD_GTK_DOCS])dnl
AC_BEFORE([$0], [GP_CHECK_DOXYGEN])dnl
AC_ARG_WITH([doc-dir],
[AS_HELP_STRING([--with-doc-dir=PATH],
[Where to install docs [default=autodetect]])])
# check for the main ("root") documentation directory
AC_MSG_CHECKING([main docdir])
if test "x${with_doc_dir}" != "x"
then # docdir is given as parameter
docdir="${with_doc_dir}"
AC_MSG_RESULT([${docdir} (from parameter)])
else # otherwise invent a docdir hopefully compatible with system policy
if test -d "/usr/share/doc"
then
maindocdir='${prefix}/share/doc'
AC_MSG_RESULT([${maindocdir} (FHS style)])
elif test -d "/usr/doc"
then
maindocdir='${prefix}/doc'
AC_MSG_RESULT([${maindocdir} (old style)])
else
maindocdir='${datadir}/doc'
AC_MSG_RESULT([${maindocdir} (default value)])
fi
AC_MSG_CHECKING([package docdir])
# check whether to include package version into documentation path
# FIXME: doesn't work properly.
if ls -d /usr/{share/,}doc/make-[0-9]* > /dev/null 2>&1
then
docdir="${maindocdir}/${PACKAGE}-${VERSION}"
AC_MSG_RESULT([${docdir} (redhat style)])
else
docdir="${maindocdir}/${PACKAGE}"
AC_MSG_RESULT([${docdir} (default style)])
fi
fi
AC_SUBST([docdir])
])dnl
dnl
dnl ####################################################################
dnl check whether to build docs and where to:
dnl
dnl * determine presence of prerequisites (only gtk-doc for now)
dnl * determine destination directory for HTML files
dnl ####################################################################
dnl
AC_DEFUN([GP_BUILD_GTK_DOCS],
[
# docdir has to be determined in advance
AC_REQUIRE([GP_CHECK_DOC_DIR])
AC_DEFUN([GP_BUILD_GTK_DOCS], [dnl
# ---------------------------------------------------------------------------
# gtk-doc: We use gtk-doc for building our documentation. However, we
# require the user to explicitly request the build.
@@ -88,27 +32,8 @@ fi
AM_CONDITIONAL([ENABLE_GTK_DOC], [$have_gtkdoc])
GP_CONFIG_MSG([build API docs with gtk-doc],[$gtkdoc_msg])
# ---------------------------------------------------------------------------
# Give the user the possibility to install html documentation in a
# user-defined location.
# ---------------------------------------------------------------------------
AC_ARG_WITH([html-dir],
[AS_HELP_STRING([--with-html-dir=PATH],
[Where to install html docs [default=autodetect]])])
AC_MSG_CHECKING([for html dir])
if test "x${with_html_dir}" = "x" ; then
htmldir="${docdir}/html"
AC_MSG_RESULT([${htmldir} (default)])
else
htmldir="${with_html_dir}"
AC_MSG_RESULT([${htmldir} (from parameter)])
fi
AC_SUBST([htmldir])
apidocdir="${htmldir}/api"
AC_SUBST([apidocdir])
])dnl
dnl
dnl

4
libgphoto2_port/gphoto-m4/gp-packaging.m4
View File

@@ -11,10 +11,6 @@ AC_DEFUN([GPKG_CHECK_LINUX],
esac
AM_CONDITIONAL([HAVE_LINUX], ["$is_linux"])
# required for docdir
# FIXME: Implicit dependency
# AC_REQUIRE(GP_CHECK_DOC_DIR)
AC_ARG_WITH([hotplug-doc-dir],
[AS_HELP_STRING([--with-hotplug-doc-dir=PATH],
[Where to install hotplug scripts as docs [default=autodetect]])])